Contract Source Code:
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)
pragma solidity ^0.8.20;
import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";
import {ContextUpgradeable} from "../utils/ContextUpgradeable.sol";
import {ERC165Upgradeable} from "../utils/introspection/ERC165Upgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";
/**
* @dev Contract module that allows children to implement role-based access
* control mechanisms. This is a lightweight version that doesn't allow enumerating role
* members except through off-chain means by accessing the contract event logs. Some
* applications may benefit from on-chain enumerability, for those cases see
* {AccessControlEnumerable}.
*
* Roles are referred to by their `bytes32` identifier. These should be exposed
* in the external API and be unique. The best way to achieve this is by
* using `public constant` hash digests:
*
* ```solidity
* bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
* ```
*
* Roles can be used to represent a set of permissions. To restrict access to a
* function call, use {hasRole}:
*
* ```solidity
* function foo() public {
* require(hasRole(MY_ROLE, msg.sender));
* ...
* }
* ```
*
* Roles can be granted and revoked dynamically via the {grantRole} and
* {revokeRole} functions. Each role has an associated admin role, and only
* accounts that have a role's admin role can call {grantRole} and {revokeRole}.
*
* By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
* that only accounts with this role will be able to grant or revoke other
* roles. More complex role relationships can be created by using
* {_setRoleAdmin}.
*
* WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
* grant and revoke this role. Extra precautions should be taken to secure
* accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
* to enforce additional security measures for this role.
*/
abstract contract AccessControlUpgradeable is Initializable, ContextUpgradeable, IAccessControl, ERC165Upgradeable {
struct RoleData {
mapping(address account => bool) hasRole;
bytes32 adminRole;
}
bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;
/// @custom:storage-location erc7201:openzeppelin.storage.AccessControl
struct AccessControlStorage {
mapping(bytes32 role => RoleData) _roles;
}
// keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.AccessControl")) - 1)) & ~bytes32(uint256(0xff))
bytes32 private constant AccessControlStorageLocation = 0x02dd7bc7dec4dceedda775e58dd541e08a116c6c53815c0bd028192f7b626800;
function _getAccessControlStorage() private pure returns (AccessControlStorage storage $) {
assembly {
$.slot := AccessControlStorageLocation
}
}
/**
* @dev Modifier that checks that an account has a specific role. Reverts
* with an {AccessControlUnauthorizedAccount} error including the required role.
*/
modifier onlyRole(bytes32 role) {
_checkRole(role);
_;
}
function __AccessControl_init() internal onlyInitializing {
}
function __AccessControl_init_unchained() internal onlyInitializing {
}
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
}
/**
* @dev Returns `true` if `account` has been granted `role`.
*/
function hasRole(bytes32 role, address account) public view virtual returns (bool) {
AccessControlStorage storage $ = _getAccessControlStorage();
return $._roles[role].hasRole[account];
}
/**
* @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
* is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
*/
function _checkRole(bytes32 role) internal view virtual {
_checkRole(role, _msgSender());
}
/**
* @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
* is missing `role`.
*/
function _checkRole(bytes32 role, address account) internal view virtual {
if (!hasRole(role, account)) {
revert AccessControlUnauthorizedAccount(account, role);
}
}
/**
* @dev Returns the admin role that controls `role`. See {grantRole} and
* {revokeRole}.
*
* To change a role's admin, use {_setRoleAdmin}.
*/
function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
AccessControlStorage storage $ = _getAccessControlStorage();
return $._roles[role].adminRole;
}
/**
* @dev Grants `role` to `account`.
*
* If `account` had not been already granted `role`, emits a {RoleGranted}
* event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*
* May emit a {RoleGranted} event.
*/
function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
_grantRole(role, account);
}
/**
* @dev Revokes `role` from `account`.
*
* If `account` had been granted `role`, emits a {RoleRevoked} event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*
* May emit a {RoleRevoked} event.
*/
function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
_revokeRole(role, account);
}
/**
* @dev Revokes `role` from the calling account.
*
* Roles are often managed via {grantRole} and {revokeRole}: this function's
* purpose is to provide a mechanism for accounts to lose their privileges
* if they are compromised (such as when a trusted device is misplaced).
*
* If the calling account had been revoked `role`, emits a {RoleRevoked}
* event.
*
* Requirements:
*
* - the caller must be `callerConfirmation`.
*
* May emit a {RoleRevoked} event.
*/
function renounceRole(bytes32 role, address callerConfirmation) public virtual {
if (callerConfirmation != _msgSender()) {
revert AccessControlBadConfirmation();
}
_revokeRole(role, callerConfirmation);
}
/**
* @dev Sets `adminRole` as ``role``'s admin role.
*
* Emits a {RoleAdminChanged} event.
*/
function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
AccessControlStorage storage $ = _getAccessControlStorage();
bytes32 previousAdminRole = getRoleAdmin(role);
$._roles[role].adminRole = adminRole;
emit RoleAdminChanged(role, previousAdminRole, adminRole);
}
/**
* @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
*
* Internal function without access restriction.
*
* May emit a {RoleGranted} event.
*/
function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
AccessControlStorage storage $ = _getAccessControlStorage();
if (!hasRole(role, account)) {
$._roles[role].hasRole[account] = true;
emit RoleGranted(role, account, _msgSender());
return true;
} else {
return false;
}
}
/**
* @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
*
* Internal function without access restriction.
*
* May emit a {RoleRevoked} event.
*/
function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
AccessControlStorage storage $ = _getAccessControlStorage();
if (hasRole(role, account)) {
$._roles[role].hasRole[account] = false;
emit RoleRevoked(role, account, _msgSender());
return true;
} else {
return false;
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/utils/Initializable.sol)
pragma solidity ^0.8.20;
/**
* @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
* behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
* external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
* function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
*
* The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
* reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
* case an upgrade adds a module that needs to be initialized.
*
* For example:
*
* [.hljs-theme-light.nopadding]
* ```solidity
* contract MyToken is ERC20Upgradeable {
* function initialize() initializer public {
* __ERC20_init("MyToken", "MTK");
* }
* }
*
* contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
* function initializeV2() reinitializer(2) public {
* __ERC20Permit_init("MyToken");
* }
* }
* ```
*
* TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
* possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
*
* CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
* that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
*
* [CAUTION]
* ====
* Avoid leaving a contract uninitialized.
*
* An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
* contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
* the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
*
* [.hljs-theme-light.nopadding]
* ```
* /// @custom:oz-upgrades-unsafe-allow constructor
* constructor() {
* _disableInitializers();
* }
* ```
* ====
*/
abstract contract Initializable {
/**
* @dev Storage of the initializable contract.
*
* It's implemented on a custom ERC-7201 namespace to reduce the risk of storage collisions
* when using with upgradeable contracts.
*
* @custom:storage-location erc7201:openzeppelin.storage.Initializable
*/
struct InitializableStorage {
/**
* @dev Indicates that the contract has been initialized.
*/
uint64 _initialized;
/**
* @dev Indicates that the contract is in the process of being initialized.
*/
bool _initializing;
}
// keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.Initializable")) - 1)) & ~bytes32(uint256(0xff))
bytes32 private constant INITIALIZABLE_STORAGE = 0xf0c57e16840df040f15088dc2f81fe391c3923bec73e23a9662efc9c229c6a00;
/**
* @dev The contract is already initialized.
*/
error InvalidInitialization();
/**
* @dev The contract is not initializing.
*/
error NotInitializing();
/**
* @dev Triggered when the contract has been initialized or reinitialized.
*/
event Initialized(uint64 version);
/**
* @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
* `onlyInitializing` functions can be used to initialize parent contracts.
*
* Similar to `reinitializer(1)`, except that in the context of a constructor an `initializer` may be invoked any
* number of times. This behavior in the constructor can be useful during testing and is not expected to be used in
* production.
*
* Emits an {Initialized} event.
*/
modifier initializer() {
// solhint-disable-next-line var-name-mixedcase
InitializableStorage storage $ = _getInitializableStorage();
// Cache values to avoid duplicated sloads
bool isTopLevelCall = !$._initializing;
uint64 initialized = $._initialized;
// Allowed calls:
// - initialSetup: the contract is not in the initializing state and no previous version was
// initialized
// - construction: the contract is initialized at version 1 (no reininitialization) and the
// current contract is just being deployed
bool initialSetup = initialized == 0 && isTopLevelCall;
bool construction = initialized == 1 && address(this).code.length == 0;
if (!initialSetup && !construction) {
revert InvalidInitialization();
}
$._initialized = 1;
if (isTopLevelCall) {
$._initializing = true;
}
_;
if (isTopLevelCall) {
$._initializing = false;
emit Initialized(1);
}
}
/**
* @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
* contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
* used to initialize parent contracts.
*
* A reinitializer may be used after the original initialization step. This is essential to configure modules that
* are added through upgrades and that require initialization.
*
* When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
* cannot be nested. If one is invoked in the context of another, execution will revert.
*
* Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
* a contract, executing them in the right order is up to the developer or operator.
*
* WARNING: Setting the version to 2**64 - 1 will prevent any future reinitialization.
*
* Emits an {Initialized} event.
*/
modifier reinitializer(uint64 version) {
// solhint-disable-next-line var-name-mixedcase
InitializableStorage storage $ = _getInitializableStorage();
if ($._initializing || $._initialized >= version) {
revert InvalidInitialization();
}
$._initialized = version;
$._initializing = true;
_;
$._initializing = false;
emit Initialized(version);
}
/**
* @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
* {initializer} and {reinitializer} modifiers, directly or indirectly.
*/
modifier onlyInitializing() {
_checkInitializing();
_;
}
/**
* @dev Reverts if the contract is not in an initializing state. See {onlyInitializing}.
*/
function _checkInitializing() internal view virtual {
if (!_isInitializing()) {
revert NotInitializing();
}
}
/**
* @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
* Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
* to any version. It is recommended to use this to lock implementation contracts that are designed to be called
* through proxies.
*
* Emits an {Initialized} event the first time it is successfully executed.
*/
function _disableInitializers() internal virtual {
// solhint-disable-next-line var-name-mixedcase
InitializableStorage storage $ = _getInitializableStorage();
if ($._initializing) {
revert InvalidInitialization();
}
if ($._initialized != type(uint64).max) {
$._initialized = type(uint64).max;
emit Initialized(type(uint64).max);
}
}
/**
* @dev Returns the highest version that has been initialized. See {reinitializer}.
*/
function _getInitializedVersion() internal view returns (uint64) {
return _getInitializableStorage()._initialized;
}
/**
* @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
*/
function _isInitializing() internal view returns (bool) {
return _getInitializableStorage()._initializing;
}
/**
* @dev Returns a pointer to the storage namespace.
*/
// solhint-disable-next-line var-name-mixedcase
function _getInitializableStorage() private pure returns (InitializableStorage storage $) {
assembly {
$.slot := INITIALIZABLE_STORAGE
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)
pragma solidity ^0.8.20;
import {Initializable} from "../proxy/utils/Initializable.sol";
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract ContextUpgradeable is Initializable {
function __Context_init() internal onlyInitializing {
}
function __Context_init_unchained() internal onlyInitializing {
}
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
function _contextSuffixLength() internal view virtual returns (uint256) {
return 0;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)
pragma solidity ^0.8.20;
import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";
/**
* @dev Implementation of the {IERC165} interface.
*
* Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
* for the additional interface id that will be supported. For example:
*
* ```solidity
* function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
* return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
* }
* ```
*/
abstract contract ERC165Upgradeable is Initializable, IERC165 {
function __ERC165_init() internal onlyInitializing {
}
function __ERC165_init_unchained() internal onlyInitializing {
}
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
return interfaceId == type(IERC165).interfaceId;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/IAccessControl.sol)
pragma solidity ^0.8.20;
/**
* @dev External interface of AccessControl declared to support ERC165 detection.
*/
interface IAccessControl {
/**
* @dev The `account` is missing a role.
*/
error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);
/**
* @dev The caller of a function is not the expected one.
*
* NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
*/
error AccessControlBadConfirmation();
/**
* @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
*
* `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
* {RoleAdminChanged} not being emitted signaling this.
*/
event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);
/**
* @dev Emitted when `account` is granted `role`.
*
* `sender` is the account that originated the contract call, an admin role
* bearer except when using {AccessControl-_setupRole}.
*/
event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);
/**
* @dev Emitted when `account` is revoked `role`.
*
* `sender` is the account that originated the contract call:
* - if using `revokeRole`, it is the admin role bearer
* - if using `renounceRole`, it is the role bearer (i.e. `account`)
*/
event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);
/**
* @dev Returns `true` if `account` has been granted `role`.
*/
function hasRole(bytes32 role, address account) external view returns (bool);
/**
* @dev Returns the admin role that controls `role`. See {grantRole} and
* {revokeRole}.
*
* To change a role's admin, use {AccessControl-_setRoleAdmin}.
*/
function getRoleAdmin(bytes32 role) external view returns (bytes32);
/**
* @dev Grants `role` to `account`.
*
* If `account` had not been already granted `role`, emits a {RoleGranted}
* event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*/
function grantRole(bytes32 role, address account) external;
/**
* @dev Revokes `role` from `account`.
*
* If `account` had been granted `role`, emits a {RoleRevoked} event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*/
function revokeRole(bytes32 role, address account) external;
/**
* @dev Revokes `role` from the calling account.
*
* Roles are often managed via {grantRole} and {revokeRole}: this function's
* purpose is to provide a mechanism for accounts to lose their privileges
* if they are compromised (such as when a trusted device is misplaced).
*
* If the calling account had been granted `role`, emits a {RoleRevoked}
* event.
*
* Requirements:
*
* - the caller must be `callerConfirmation`.
*/
function renounceRole(bytes32 role, address callerConfirmation) external;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)
pragma solidity ^0.8.20;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*
* ==== Security Considerations
*
* There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
* expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
* considered as an intention to spend the allowance in any specific way. The second is that because permits have
* built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
* take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
* generally recommended is:
*
* ```solidity
* function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
* try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
* doThing(..., value);
* }
*
* function doThing(..., uint256 value) public {
* token.safeTransferFrom(msg.sender, address(this), value);
* ...
* }
* ```
*
* Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
* `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
* {SafeERC20-safeTransferFrom}).
*
* Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
* contracts should have entry points that don't rely on permit.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*
* CAUTION: See Security Considerations above.
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.20;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the value of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the value of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves a `value` amount of tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 value) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets a `value` amount of tokens as the allowance of `spender` over the
* caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 value) external returns (bool);
/**
* @dev Moves a `value` amount of tokens from `from` to `to` using the
* allowance mechanism. `value` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(address from, address to, uint256 value) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.20;
import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
/**
* @dev An operation with an ERC20 token failed.
*/
error SafeERC20FailedOperation(address token);
/**
* @dev Indicates a failed `decreaseAllowance` request.
*/
error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);
/**
* @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeTransfer(IERC20 token, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
}
/**
* @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
* calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
*/
function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
}
/**
* @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
uint256 oldAllowance = token.allowance(address(this), spender);
forceApprove(token, spender, oldAllowance + value);
}
/**
* @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
* value, non-reverting calls are assumed to be successful.
*/
function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
unchecked {
uint256 currentAllowance = token.allowance(address(this), spender);
if (currentAllowance < requestedDecrease) {
revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
}
forceApprove(token, spender, currentAllowance - requestedDecrease);
}
}
/**
* @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
* to be set to zero before setting it to a non-zero value, such as USDT.
*/
function forceApprove(IERC20 token, address spender, uint256 value) internal {
bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));
if (!_callOptionalReturnBool(token, approvalCall)) {
_callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
_callOptionalReturn(token, approvalCall);
}
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data);
if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
revert SafeERC20FailedOperation(address(token));
}
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*
* This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
*/
function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
// and not revert is the subcall reverts.
(bool success, bytes memory returndata) = address(token).call(data);
return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)
pragma solidity ^0.8.20;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev The ETH balance of the account is not enough to perform the operation.
*/
error AddressInsufficientBalance(address account);
/**
* @dev There's no code at `target` (it is not a contract).
*/
error AddressEmptyCode(address target);
/**
* @dev A call to an address target failed. The target may have reverted.
*/
error FailedInnerCall();
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
if (address(this).balance < amount) {
revert AddressInsufficientBalance(address(this));
}
(bool success, ) = recipient.call{value: amount}("");
if (!success) {
revert FailedInnerCall();
}
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason or custom error, it is bubbled
* up by this function (like regular Solidity function calls). However, if
* the call reverted with no returned reason, this function reverts with a
* {FailedInnerCall} error.
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*/
function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
if (address(this).balance < value) {
revert AddressInsufficientBalance(address(this));
}
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
* was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
* unsuccessful call.
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata
) internal view returns (bytes memory) {
if (!success) {
_revert(returndata);
} else {
// only check if target is a contract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
if (returndata.length == 0 && target.code.length == 0) {
revert AddressEmptyCode(target);
}
return returndata;
}
}
/**
* @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
* revert reason or with a default {FailedInnerCall} error.
*/
function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
if (!success) {
_revert(returndata);
} else {
return returndata;
}
}
/**
* @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
*/
function _revert(bytes memory returndata) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert FailedInnerCall();
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)
pragma solidity ^0.8.20;
/**
* @dev Interface of the ERC165 standard, as defined in the
* https://eips.ethereum.org/EIPS/eip-165[EIP].
*
* Implementers can declare support of contract interfaces, which can then be
* queried by others ({ERC165Checker}).
*
* For an implementation, see {ERC165}.
*/
interface IERC165 {
/**
* @dev Returns true if this contract implements the interface defined by
* `interfaceId`. See the corresponding
* https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
* to learn more about how these ids are created.
*
* This function call must use less than 30 000 gas.
*/
function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/Math.sol)
pragma solidity ^0.8.20;
/**
* @dev Standard math utilities missing in the Solidity language.
*/
library Math {
/**
* @dev Muldiv operation overflow.
*/
error MathOverflowedMulDiv();
enum Rounding {
Floor, // Toward negative infinity
Ceil, // Toward positive infinity
Trunc, // Toward zero
Expand // Away from zero
}
/**
* @dev Returns the addition of two unsigned integers, with an overflow flag.
*/
function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
uint256 c = a + b;
if (c < a) return (false, 0);
return (true, c);
}
}
/**
* @dev Returns the subtraction of two unsigned integers, with an overflow flag.
*/
function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
if (b > a) return (false, 0);
return (true, a - b);
}
}
/**
* @dev Returns the multiplication of two unsigned integers, with an overflow flag.
*/
function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
// Gas optimization: this is cheaper than requiring 'a' not being zero, but the
// benefit is lost if 'b' is also tested.
// See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
if (a == 0) return (true, 0);
uint256 c = a * b;
if (c / a != b) return (false, 0);
return (true, c);
}
}
/**
* @dev Returns the division of two unsigned integers, with a division by zero flag.
*/
function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
if (b == 0) return (false, 0);
return (true, a / b);
}
}
/**
* @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
*/
function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
if (b == 0) return (false, 0);
return (true, a % b);
}
}
/**
* @dev Returns the largest of two numbers.
*/
function max(uint256 a, uint256 b) internal pure returns (uint256) {
return a > b ? a : b;
}
/**
* @dev Returns the smallest of two numbers.
*/
function min(uint256 a, uint256 b) internal pure returns (uint256) {
return a < b ? a : b;
}
/**
* @dev Returns the average of two numbers. The result is rounded towards
* zero.
*/
function average(uint256 a, uint256 b) internal pure returns (uint256) {
// (a + b) / 2 can overflow.
return (a & b) + (a ^ b) / 2;
}
/**
* @dev Returns the ceiling of the division of two numbers.
*
* This differs from standard division with `/` in that it rounds towards infinity instead
* of rounding towards zero.
*/
function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
if (b == 0) {
// Guarantee the same behavior as in a regular Solidity division.
return a / b;
}
// (a + b - 1) / b can overflow on addition, so we distribute.
return a == 0 ? 0 : (a - 1) / b + 1;
}
/**
* @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or
* denominator == 0.
* @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv) with further edits by
* Uniswap Labs also under MIT license.
*/
function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
unchecked {
// 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
// use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
// variables such that product = prod1 * 2^256 + prod0.
uint256 prod0 = x * y; // Least significant 256 bits of the product
uint256 prod1; // Most significant 256 bits of the product
assembly {
let mm := mulmod(x, y, not(0))
prod1 := sub(sub(mm, prod0), lt(mm, prod0))
}
// Handle non-overflow cases, 256 by 256 division.
if (prod1 == 0) {
// Solidity will revert if denominator == 0, unlike the div opcode on its own.
// The surrounding unchecked block does not change this fact.
// See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
return prod0 / denominator;
}
// Make sure the result is less than 2^256. Also prevents denominator == 0.
if (denominator <= prod1) {
revert MathOverflowedMulDiv();
}
///////////////////////////////////////////////
// 512 by 256 division.
///////////////////////////////////////////////
// Make division exact by subtracting the remainder from [prod1 prod0].
uint256 remainder;
assembly {
// Compute remainder using mulmod.
remainder := mulmod(x, y, denominator)
// Subtract 256 bit number from 512 bit number.
prod1 := sub(prod1, gt(remainder, prod0))
prod0 := sub(prod0, remainder)
}
// Factor powers of two out of denominator and compute largest power of two divisor of denominator.
// Always >= 1. See https://cs.stackexchange.com/q/138556/92363.
uint256 twos = denominator & (0 - denominator);
assembly {
// Divide denominator by twos.
denominator := div(denominator, twos)
// Divide [prod1 prod0] by twos.
prod0 := div(prod0, twos)
// Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
twos := add(div(sub(0, twos), twos), 1)
}
// Shift in bits from prod1 into prod0.
prod0 |= prod1 * twos;
// Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
// that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
// four bits. That is, denominator * inv = 1 mod 2^4.
uint256 inverse = (3 * denominator) ^ 2;
// Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also
// works in modular arithmetic, doubling the correct bits in each step.
inverse *= 2 - denominator * inverse; // inverse mod 2^8
inverse *= 2 - denominator * inverse; // inverse mod 2^16
inverse *= 2 - denominator * inverse; // inverse mod 2^32
inverse *= 2 - denominator * inverse; // inverse mod 2^64
inverse *= 2 - denominator * inverse; // inverse mod 2^128
inverse *= 2 - denominator * inverse; // inverse mod 2^256
// Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
// This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
// less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
// is no longer required.
result = prod0 * inverse;
return result;
}
}
/**
* @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
*/
function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
uint256 result = mulDiv(x, y, denominator);
if (unsignedRoundsUp(rounding) && mulmod(x, y, denominator) > 0) {
result += 1;
}
return result;
}
/**
* @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded
* towards zero.
*
* Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
*/
function sqrt(uint256 a) internal pure returns (uint256) {
if (a == 0) {
return 0;
}
// For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
//
// We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
// `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
//
// This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
// → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
// → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
//
// Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
uint256 result = 1 << (log2(a) >> 1);
// At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
// since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
// every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
// into the expected uint128 result.
unchecked {
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
return min(result, a / result);
}
}
/**
* @notice Calculates sqrt(a), following the selected rounding direction.
*/
function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = sqrt(a);
return result + (unsignedRoundsUp(rounding) && result * result < a ? 1 : 0);
}
}
/**
* @dev Return the log in base 2 of a positive value rounded towards zero.
* Returns 0 if given 0.
*/
function log2(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >> 128 > 0) {
value >>= 128;
result += 128;
}
if (value >> 64 > 0) {
value >>= 64;
result += 64;
}
if (value >> 32 > 0) {
value >>= 32;
result += 32;
}
if (value >> 16 > 0) {
value >>= 16;
result += 16;
}
if (value >> 8 > 0) {
value >>= 8;
result += 8;
}
if (value >> 4 > 0) {
value >>= 4;
result += 4;
}
if (value >> 2 > 0) {
value >>= 2;
result += 2;
}
if (value >> 1 > 0) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 2, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log2(value);
return result + (unsignedRoundsUp(rounding) && 1 << result < value ? 1 : 0);
}
}
/**
* @dev Return the log in base 10 of a positive value rounded towards zero.
* Returns 0 if given 0.
*/
function log10(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >= 10 ** 64) {
value /= 10 ** 64;
result += 64;
}
if (value >= 10 ** 32) {
value /= 10 ** 32;
result += 32;
}
if (value >= 10 ** 16) {
value /= 10 ** 16;
result += 16;
}
if (value >= 10 ** 8) {
value /= 10 ** 8;
result += 8;
}
if (value >= 10 ** 4) {
value /= 10 ** 4;
result += 4;
}
if (value >= 10 ** 2) {
value /= 10 ** 2;
result += 2;
}
if (value >= 10 ** 1) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 10, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log10(value);
return result + (unsignedRoundsUp(rounding) && 10 ** result < value ? 1 : 0);
}
}
/**
* @dev Return the log in base 256 of a positive value rounded towards zero.
* Returns 0 if given 0.
*
* Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
*/
function log256(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >> 128 > 0) {
value >>= 128;
result += 16;
}
if (value >> 64 > 0) {
value >>= 64;
result += 8;
}
if (value >> 32 > 0) {
value >>= 32;
result += 4;
}
if (value >> 16 > 0) {
value >>= 16;
result += 2;
}
if (value >> 8 > 0) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 256, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log256(value);
return result + (unsignedRoundsUp(rounding) && 1 << (result << 3) < value ? 1 : 0);
}
}
/**
* @dev Returns whether a provided rounding mode is considered rounding up for unsigned integers.
*/
function unsignedRoundsUp(Rounding rounding) internal pure returns (bool) {
return uint8(rounding) % 2 == 1;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";
interface IAffiliateRegistry is IAccessControl {
struct Affiliate {
uint256 lifetimeSales;
uint256 lifetimeSessionValue;
address receiver;
uint32 sessionShareTier;
uint32 saleShareTier;
uint64 uniqueWallets;
}
error AffiliateRegistry__AlreadyRegistered();
error AffiliateRegistry__NoSelfAffiliate();
error AffiliateRegistry__AffiliateNotRegistered();
error AffiliateRegistry__ZeroValue();
error AffiliateRegistry__NoPermission();
error AffiliateRegistry__ZeroAddress();
event AffiliateRegistered(uint256 indexed id, address indexed receiver);
event ReceiverChanged(uint256 indexed id, address indexed receiver);
event PlayerAssigned(uint256 indexed id, address indexed player);
event SessionShareChanged(uint256 indexed id, uint256 newSessionShare);
event SaleShareChanged(uint256 indexed id, uint256 newSaleShare);
event SaleShareTierChanged(uint32 tier, uint256 saleShare);
event SessionShareTierChanged(uint32 tier, uint256 sessionShare);
event SaleRegistered(uint256 affiliateId, uint256 totalPrice, address receiver, uint256 amount);
event SessionRegistered(uint256 affiliateId, uint256 totalPrice, address receiver, uint256 amount);
function assignPlayer(address _player, uint256 _affiliateId) external;
function setAffiliateSessionShareTier(uint256, uint32) external;
function setAffiliateSaleShareTier(uint256, uint32) external;
function registerNewAffiliate(address _revenueReceiver) external returns (uint256 _affiliateId);
function registerSale(address _player, uint256 _fees) external returns (address, uint256);
function registerSession(address _player, uint256 _fees) external returns (address, uint256);
function changeReceiver(uint256 _affiliateId, address _newReceiver) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {IAffiliateRegistry} from "../../affiliateRegistry/IAffiliateRegistry.sol";
interface IFeeSplitter {
event MaxDevFeePercentageSet(uint256 maxDevFeePercentage);
event ProtocolFeePercentageSet(uint256 protocolFeePercentage);
event ProtocolFeeReceiverSet(address protocolFeeReceiver);
function maxDevFeePercentage() external view returns (uint256);
function calculateFees(
address _gameDev,
address _player,
uint256 _totalCollateral,
uint256 _gameDevFeePercentage
) external returns (address[] memory, uint256[] memory, uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
interface IPlayerCard {
error PlayerCard__SoulboundToken();
event BaseUriSet(string uri);
function mintCardIfRequired(address to) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
interface IPlaythroughTracker {
struct State {
uint256 total;
mapping(uint256 offeringId => uint256) totalPerOffering;
}
event RequirementAdded(address account, address creditId, uint256 offeringId, uint256 amount);
event AccountProgressed(address account, address creditId, uint256 amount);
event RequirementsAdded(address[] accounts, uint256[] amounts, address creditId, uint256 offeringId);
event BonusCashSet(address bonusCash);
function isLocked(address _account, address _creditId) external view returns (bool);
function addRequirements(
address[] calldata _accounts,
uint256[] calldata _amounts,
address _creditId,
uint256 _offeringId
) external;
function progressAccount(address _account, address _creditId, address _gameAddress, uint256 _amount) external;
function progressAccount(uint256 _offeringId, address _creditId, address _account, uint256 _amount) external;
function progressAccounts(
uint256 _offeringId,
address _creditId,
address[] calldata _accounts,
uint256[] memory _amounts
) external;
function undoOffering(uint256 _offeringId, address _creditId, address _account) external;
function undoOfferings(uint256 _offeringId, address _creditId, address[] calldata _accounts) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {ICredits} from "../../token/credits/ICredits.sol";
import {IBonusCash} from "../../token/bonusCash/IBonusCash.sol";
import {IPriceFeed} from "../../utils/priceFeed/IPriceFeed.sol";
import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";
interface ITournament is IAccessControl {
struct Config {
uint256 entryFee; // credit fee to enter tournament (new entry for a new score)
uint256 rebuyFee; // credit fee to rebuy into tournament (re-attempt an existing entry to try to improve score)
bool isExactFee; // if true, above fees are exact required fees. if false, above fees are minimum fees
uint64 entryLimit; // max number of entries allowed per player
uint64 maxEntriesPerRoom; // max number of entries allowed per room
uint64 rebuyLimit; // max number of rebuys allowed per player per entry
uint64 startDate; // start date of tournament (block timestamp)
uint64 endDate; // end date of tournament (block timestamp)
uint64 ticketProfitToTickets; // % of profit from ticket entry converted to ticket payout (in wei)
uint64 creditProfitToTickets; // % of profit from credit entry converted to credit payout (in wei)
uint64 creditEntryToTickets; // % of credit entry converted to ticket payout (in wei)
uint64 entryDuration; // duration in seconds of entry period for a room once the room is opened
uint64 tournamentDuration; // duration in seconds of tournament instance (room) once started
uint64 payoutDuration; // duration in seconds to allow payouts for after tournament ends
uint96 creditRatio; // ratio of collateral to credits (gets set during register transaction)
address creditId; // credit id to use for entry fee (the id is the collateral token address)
uint256 bonusCollateral; // amount of collateral to request each time it's needed
bytes32 priceFeedPair; // pair to use for price feed (use bytes32(0) for a flat credit fee)
}
struct Entry {
uint256 ticketBasedCollateral;
uint256 creditBasedCollateral;
uint256 totalCollateralPaid;
uint248 rebuyCount;
bool payoutReceived;
}
struct EntryParams {
address account;
uint256 tournamentId;
uint256 roomId;
address swapFromCredit;
uint256 swapMinCollateral;
uint256 entryAmount;
}
struct EntryData {
uint256 entryCount;
// roomId => entry
mapping(uint256 => Entry) entries;
}
struct Room {
uint256 totalPrizePool;
uint256 collateral;
uint64 totalEntries;
uint64 startDate; // block.timestamp + config.entryDuration
uint64 endDate; // startDate + config.tournamentDuration
uint56 payoutEndDate; // endDate + config.payoutDuration
bool bonusCashCollected;
}
struct Result {
address player;
uint256 multiplier;
}
event TournamentConfigUpdated(uint256 indexed tournamentId, Config config);
event TournamentEntered(
uint256 indexed tournamentId,
uint256 indexed roomId,
address indexed player,
uint registrationFee,
bool isRebuy
);
event ResultsSubmitted(uint256 tournamentId, uint256 _roomId, Result[] results);
event GameDevSet(address gameDev);
event BonusContractSet(address bonusContract);
event SwapExecutorSet(address swapExecutor);
event SwapDeadlineSet(uint256 deadline);
event FeeSplitterSet(address feeSplitter);
event TournamentCleansed(uint256 tournamentId, uint256 roomId, address target, uint256 amount);
event RebuyBonusCashAllowedSet(bool allowed);
event SwapEnabledChanged(address indexed from, address indexed to, bool enabled);
event PriceFeedSet(address priceFeed);
event RoomOpened(uint256 indexed tournamentId, uint256 indexed roomId);
event ExcessTokensWithdrawn(address token, address to, uint256 excessAmount);
event EmergencyCollateralWithdrawn(address token, address to, uint256 amount);
event DevFeePercentageSet(uint256 percentage);
event CollateralResolverMaxSet(address indexed creditId, uint256 collateralResolverMax);
event EmergencyCollateralDeposited(address indexed creditId, uint256 amount);
// Tournament IDs
function tournamentCount() external view returns (uint256);
// Game Dev address (receives excess collateral after tournaments end)
function gameDev() external view returns (address);
// Allow bonus cash to be used for rebuy
function rebuyBonusCashAllowed() external view returns (bool);
/**
* @notice Get the tournament config set by contract admin
*
* @param _tournamentId ID of the tournament
*/
function getTournament(uint256 _tournamentId) external view returns (Config memory);
/**
* @notice Get the entry for a player in a room
*
* @param _tournamentId ID of the tournament
* @param _player Address of the player
* @param _roomId ID of the tournament room
*/
function getEntry(uint256 _tournamentId, address _player, uint256 _roomId) external view returns (Entry memory);
/**
* @notice Get metadata for a tournament room
*
* @param _tournamentId ID of the tournament
* @param _roomId ID of the tournament room
*/
function getRoom(uint256 _tournamentId, uint256 _roomId) external view returns (Room memory);
/**
* @notice Update the address of the game developer
*
* @param _gameDev Address of the game developer
*/
function setGameDev(address _gameDev) external;
/**
* @notice Set whether bonus cash can be used for rebuy
*
* @param _allowed Whether bonus cash can be used for rebuy
*/
function setRebuyBonusCashAllowed(bool _allowed) external;
/**
* @notice Admin function to register a new tournament
*
* @param _c Config struct for the tournament
*/
function register(Config memory _c) external returns (uint256 _tournamentId);
/**
* @notice Admin function to update the config of a tournament
*
* @param _tournamentId ID of the tournament
* @param _c Config struct for the tournament
*/
function updateTournamentConfig(uint256 _tournamentId, Config memory _c) external;
/**
* @notice Enters a player into a tournament room. If the room does not exist, it will be created.
*
* @dev A player can only enter a specific room once.
*
* @param _params entry params struct
*/
function enter(EntryParams calldata _params) external payable;
/**
* @notice Submits the results of a tournament room. Payouts are calculated and credits are minted to players.
*
* @param _tournamentId ID of the tournament
* @param _roomId ID of the tournament room
* @param _results Array of results for the room
*/
function submitResults(uint256 _tournamentId, uint256 _roomId, Result[] memory _results) external;
/**
* @notice Cleans up a tournament room after the payout duration has ended. Returns any remaining collateral to the game dev or bonus contract.
*
* @param _tournamentId ID of the tournament
* @param _roomId ID of the tournament room
*/
function cleanup(uint256 _tournamentId, uint256 _roomId) external;
function createRoomBatch(
uint256 _tournamentId,
uint256[] calldata _roomIds,
uint64[] calldata _openTimestamps
) external;
function createRoom(uint256 _tournamentId, uint256 _roomId, uint64 _openTimestamp) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";
import {PVMath} from "../../libraries/PVMath.sol";
import {ITournament, ICredits, IBonusCash, IPriceFeed} from "./ITournament.sol";
import {IFeeSplitter} from "../../defi/feeSplitter/IFeeSplitter.sol";
import {ITickets} from "../../token/tickets/ITickets.sol";
import {ITokenRegistry} from "../../token/tokenRegistry/ITokenRegistry.sol";
import {IPlaythroughTracker} from "../../game/playthroughTracker/IPlaythroughTracker.sol";
import {IPlayerCard} from "../playerCard/IPlayerCard.sol";
import {ISwapExecutor} from "../../interfaces/ISwapExecutor.sol";
/**
* @title Tournament
*
* @author Jack Chuma, Niftydude
*
* @notice Contract for managing tournaments. Handles tournament entries and result submission for payouts.
*/
contract Tournament is Initializable, AccessControlUpgradeable, ITournament {
using PVMath for uint256;
using Math for uint256;
using SafeERC20 for IERC20;
ITickets immutable TICKETS;
ICredits immutable CREDITS;
IPlayerCard immutable PLAYER_CARD;
IPlaythroughTracker immutable PLAYTHROUGH_TRACKER;
IFeeSplitter immutable FEE_SPLITTER;
ITokenRegistry immutable TOKEN_REGISTRY;
IBonusCash immutable BONUS_CASH;
ISwapExecutor public swapExecutor;
IPriceFeed public priceFeed;
bytes32 constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
bytes32 constant RELAYER_ROLE = keccak256("RELAYER_ROLE");
// Tournament IDs
uint256 public tournamentCount;
// Game Dev address (receives excess collateral after tournaments end)
address public gameDev;
// Allow bonus cash to be used for rebuy
bool public rebuyBonusCashAllowed;
// time to wait for swap to confirm
uint256 public swapDeadline;
// dev fee in percent scaled to 1e18
uint256 public devFeePercentage;
// Tournament ID => Config
mapping(uint256 => Config) tournaments;
// Tournament ID => Room ID => Room
mapping(uint256 => mapping(uint256 => Room)) rooms;
// Tournament ID => Player => EntryData
mapping(uint256 => mapping(address => EntryData)) public players;
// from token => to token => true if swap is enabled
mapping(address => mapping(address => bool)) public swapEnabled;
// credit id => total collateral held
mapping(address => uint256) public totalCollateral;
mapping(address => uint256) public emergencyCollateralBalance;
mapping(address => uint256) public collateralResolverMax;
constructor(
ITickets _tickets,
ICredits _credits,
IPlayerCard _playerCard,
IPlaythroughTracker _playthroughTracker,
IBonusCash _bonusCash,
IFeeSplitter _feeSplitter,
ITokenRegistry _tokenRegistry
) {
TICKETS = _tickets;
CREDITS = _credits;
PLAYER_CARD = _playerCard;
PLAYTHROUGH_TRACKER = _playthroughTracker;
BONUS_CASH = _bonusCash;
FEE_SPLITTER = _feeSplitter;
TOKEN_REGISTRY = _tokenRegistry;
_disableInitializers();
}
function __Tournament_init(address _superAdmin, address _gameDev, uint256 _swapDeadline) public initializer {
_grantRole(DEFAULT_ADMIN_ROLE, _superAdmin);
_grantRole(ADMIN_ROLE, _superAdmin);
gameDev = _gameDev;
swapDeadline = _swapDeadline;
}
/**
* @notice Get the entry for a player in a room
*
* @param _tournamentId ID of the tournament
* @param _player Address of the player
* @param _roomId ID of the tournament room
*/
function getEntry(uint256 _tournamentId, address _player, uint256 _roomId) external view returns (Entry memory) {
return players[_tournamentId][_player].entries[_roomId];
}
/**
* @notice Get the tournament config set by contract admin
*
* @param _tournamentId ID of the tournament
*/
function getTournament(uint256 _tournamentId) external view returns (Config memory) {
return tournaments[_tournamentId];
}
/**
* @notice Get metadata for a tournament room
*
* @param _tournamentId ID of the tournament
* @param _roomId ID of the tournament room
*/
function getRoom(uint256 _tournamentId, uint256 _roomId) external view returns (Room memory) {
return rooms[_tournamentId][_roomId];
}
/**
* @notice Update the address of the game developer
*
* @param _gameDev Address of the game developer
*/
function setGameDev(address _gameDev) external onlyRole(ADMIN_ROLE) {
require(_gameDev != address(0), "T: InvalidGameDev");
gameDev = _gameDev;
emit GameDevSet(_gameDev);
}
/**
* @notice Update the address of the swap executor
*
* @param _swapExecutor Address of the swap executor
*/
function setSwapExecutor(address _swapExecutor) external onlyRole(ADMIN_ROLE) {
require(CREDITS.swapImplEnabled(_swapExecutor), "T: InvalidSwapExecutor");
swapExecutor = ISwapExecutor(_swapExecutor);
emit SwapExecutorSet(_swapExecutor);
}
/**
* @notice Update the address of the price feed
*
* @param _priceFeed Address of the price feed implementation
*/
function setPriceFeed(address _priceFeed) external onlyRole(ADMIN_ROLE) {
priceFeed = IPriceFeed(_priceFeed);
emit PriceFeedSet(_priceFeed);
}
/**
* @notice Update the dev fee percentage
*
* @param _devFeePercentage dev fee percentage
*/
function setDevFeePercentage(uint256 _devFeePercentage) external onlyRole(ADMIN_ROLE) {
require(_devFeePercentage <= FEE_SPLITTER.maxDevFeePercentage(), "T: IvalidDevFee");
devFeePercentage = _devFeePercentage;
emit DevFeePercentageSet(_devFeePercentage);
}
/**
* @notice Update the deadline for swap to confirm
*
* @param _swapDeadline time in seconds to wait for swap to confirm
*/
function setSwapDeadline(uint256 _swapDeadline) external onlyRole(ADMIN_ROLE) {
swapDeadline = _swapDeadline;
emit SwapDeadlineSet(_swapDeadline);
}
/**
* @notice Update the treshold
*
* @param _creditId credit type to set max for
* @param _collateralResolverMax time in seconds to wait for swap to confirm
*/
function setCollateralResolverMax(address _creditId, uint256 _collateralResolverMax) external onlyRole(ADMIN_ROLE) {
collateralResolverMax[_creditId] = _collateralResolverMax;
emit CollateralResolverMaxSet(_creditId, _collateralResolverMax);
}
/**
* @notice Set whether bonus cash can be used for rebuy
*
* @param _allowed Whether bonus cash can be used for rebuy
*/
function setRebuyBonusCashAllowed(bool _allowed) external onlyRole(ADMIN_ROLE) {
rebuyBonusCashAllowed = _allowed;
emit RebuyBonusCashAllowedSet(_allowed);
}
/**
* @notice Set whether swapping a credit type token pair is allowed
*
* @param _from token to swap from
* @param _to token to swap to
* @param _enabled true if swap is enabled
*/
function setSwapEnabled(address _from, address _to, bool _enabled) external onlyRole(ADMIN_ROLE) {
swapEnabled[_from][_to] = _enabled;
emit SwapEnabledChanged(_from, _to, _enabled);
}
/**
* @notice Admin function to register a new tournament
*
* @param _c Config struct for the tournament
*/
function register(Config memory _c) external onlyRole(ADMIN_ROLE) returns (uint256 _tournamentId) {
require(_c.endDate >= block.timestamp, "T: EndDateBeforeNow");
require(TOKEN_REGISTRY.isApproved(_c.creditId), "T: InvalidCreditId");
_validateTournamentConfig(_c);
_tournamentId = _getNextTournamentId();
Config storage _config = tournaments[_tournamentId];
_config.creditId = _c.creditId;
_config.creditRatio = uint96(CREDITS.tokenPerCreditRatio(_config.creditId));
_config.priceFeedPair = _c.priceFeedPair;
_config.isExactFee = _c.isExactFee;
IERC20(_config.creditId).forceApprove(address(CREDITS), type(uint256).max);
IERC20(_config.creditId).forceApprove(address(TICKETS), type(uint256).max);
_updateTournamentConfig(_config, _tournamentId, _c);
}
/**
* @notice Admin function to update the config of a tournament
*
* @param _tournamentId ID of the tournament
* @param _c Config struct for the tournament
*/
function updateTournamentConfig(uint256 _tournamentId, Config memory _c) external onlyRole(ADMIN_ROLE) {
_validateTournamentId(_tournamentId);
_validateTournamentConfig(_c);
Config storage _config = tournaments[_tournamentId];
require(block.timestamp < _config.endDate, "T: TournamentOver");
_updateTournamentConfig(_config, _tournamentId, _c);
}
/**
* @notice Opens new rooms for an active tournament
*
* @param _tournamentId ID of the tournament
* @param _roomIds array containing IDs of the tournament rooms
*/
function createRoomBatch(
uint256 _tournamentId,
uint256[] calldata _roomIds,
uint64[] calldata _openTimestamps
) external onlyRole(RELAYER_ROLE) {
_validateTournamentId(_tournamentId);
for (uint256 i; i < _roomIds.length; i++) {
Config storage _config = tournaments[_tournamentId];
Room storage _room = rooms[_tournamentId][_roomIds[i]];
require(_room.startDate == 0, "T: Room already active");
_createRoom(_tournamentId, _roomIds[i], _openTimestamps[i], _config, _room);
}
}
/**
* @notice Opens a new room for an active tournament
*
* @param _tournamentId ID of the tournament
* @param _roomId ID of the tournament room
*/
function createRoom(uint256 _tournamentId, uint256 _roomId, uint64 _openTimestamp) external onlyRole(RELAYER_ROLE) {
_validateTournamentId(_tournamentId);
Config storage _config = tournaments[_tournamentId];
Room storage _room = rooms[_tournamentId][_roomId];
require(_room.startDate == 0, "T: Room already active");
_createRoom(_tournamentId, _roomId, _openTimestamp, _config, _room);
}
/**
* @notice Enters a player into a tournament room. If the room does not exist, it will be created.
*
* @dev A player can only enter a specific room once.
*
* @param _params entry params struct
*/
function enter(EntryParams calldata _params) external payable onlyRole(RELAYER_ROLE) {
bool _isRebuy = _validateEntrance(_params.tournamentId, _params.roomId, _params.account, _params.entryAmount);
bool _useBonusCash = _isRebuy ? rebuyBonusCashAllowed : true;
Config memory _config = tournaments[_params.tournamentId];
uint256 _ticketBalance = TICKETS.balanceOf(_params.account, _config.creditId);
uint256 _creditBalance = CREDITS.balanceOf(_params.account, _config.creditId);
uint256 _creditsAndTicketsRequired = getCreditsRequired(
_params.entryAmount,
_config.priceFeedPair,
_config.creditRatio
);
uint256 _creditsAndTicketsRequiredAfterBonusCash = _useBonusCash
? BONUS_CASH.spendRequiredAmount(
_params.account,
_config.creditId,
_ticketBalance,
_creditBalance,
_params.tournamentId,
_creditsAndTicketsRequired
)
: _creditsAndTicketsRequired;
_creditBalance += _handleCreditSwapOrPurchaseIfNeeded(
_params.account,
_params.swapFromCredit,
_params.swapMinCollateral,
_config.creditId,
_creditsAndTicketsRequiredAfterBonusCash,
_creditBalance,
_ticketBalance
);
uint256 _collateral = _payFee(
_params,
_creditsAndTicketsRequired,
_creditsAndTicketsRequiredAfterBonusCash,
_creditBalance
);
emit TournamentEntered(_params.tournamentId, _params.roomId, _params.account, _collateral, _isRebuy);
}
/**
* @notice Allows any address with a balance and approval to add collateral to a given roomId
*
* @param _creditId ID of the tournament
* @param _amount Amount of collateral to add
*/
function depositEmergencyCollateral(address _creditId, uint256 _amount) external {
IERC20(_creditId).safeTransferFrom(msg.sender, address(this), _amount);
totalCollateral[_creditId] += _amount;
emergencyCollateralBalance[_creditId] += _amount;
emit EmergencyCollateralDeposited(_creditId, _amount);
}
/**
* @notice Submits the results of a tournament room. Payouts are calculated and credits are minted to players.
*
* @param _tournamentId ID of the tournament
* @param _roomId ID of the tournament room
* @param _results Array of results for the room
*/
function submitResults(
uint256 _tournamentId,
uint256 _roomId,
Result[] memory _results
) external onlyRole(RELAYER_ROLE) {
_validateTournamentId(_tournamentId);
Config storage _config = tournaments[_tournamentId];
Room storage _room = rooms[_tournamentId][_roomId];
require(block.timestamp >= _room.endDate, "T: TournamentActive");
require(block.timestamp < _room.payoutEndDate, "T: PayoutDurationOver");
address[] memory _players = new address[](_results.length);
uint256[] memory _ticketAmounts = new uint256[](_results.length);
uint256[] memory _creditAmounts = new uint256[](_results.length);
uint256 _totalPayout;
for (uint256 i; i < _results.length; i++) {
Result memory _result = _results[i];
_players[i] = _result.player;
(_ticketAmounts[i], _creditAmounts[i]) = _processPayout(_tournamentId, _result, _roomId, _config);
unchecked {
_totalPayout += _ticketAmounts[i] + _creditAmounts[i];
}
}
_totalPayout *= _config.creditRatio;
if (_room.totalPrizePool < _totalPayout) {
_resolveUndercollateralization(_room, _config.creditId, _totalPayout);
}
_room.totalPrizePool -= _totalPayout;
if (_room.collateral < _totalPayout) {
_requestBonusCashCollateral(_room, _config, _totalPayout, _tournamentId);
} else {
_room.collateral -= _totalPayout;
totalCollateral[_config.creditId] -= _totalPayout;
}
TICKETS.mintBatch(_config.creditId, _players, _ticketAmounts);
CREDITS.mintBatch(_config.creditId, _players, _creditAmounts);
emit ResultsSubmitted(_tournamentId, _roomId, _results);
}
/**
* @notice Cleans up a tournament room after the payout duration has ended. Returns any remaining collateral to the game dev or bonus contract.
*
* @param _tournamentId ID of the tournament
* @param _roomId ID of the tournament room
*/
function cleanup(uint256 _tournamentId, uint256 _roomId) external {
_validateTournamentId(_tournamentId);
Config storage _config = tournaments[_tournamentId];
Room storage _room = rooms[_tournamentId][_roomId];
require(_room.collateral > 0, "T: NoCollateralToReturn");
require(block.timestamp >= _room.payoutEndDate, "T: PayoutDurationNotOver");
address _target = gameDev;
uint256 _amount = _room.collateral;
uint256 _bonusCollateral = 0;
_room.collateral = 0;
totalCollateral[_config.creditId] -= _amount;
emit TournamentCleansed(_tournamentId, _roomId, _target, _amount);
if (_room.bonusCashCollected) {
_target = address(BONUS_CASH);
_bonusCollateral = _amount;
} else {
IERC20(_config.creditId).safeTransfer(gameDev, _amount);
}
if (_bonusCollateral > 0) {
IERC20(_config.creditId).forceApprove(address(BONUS_CASH), _bonusCollateral);
}
BONUS_CASH.endTournament(_config.creditId, _tournamentId, _bonusCollateral);
}
/**
* @notice Withdraw emergency collateral
*
* @param _creditId token address
* @param _to token receiver address
*/
function withdrawEmergencyCollateral(
address _creditId,
address _to,
uint256 _amount
) external onlyRole(ADMIN_ROLE) {
require(emergencyCollateralBalance[_creditId] >= _amount, "T: InsufficientBalance");
emergencyCollateralBalance[_creditId] -= _amount;
IERC20(_creditId).safeTransfer(_to, _amount);
emit EmergencyCollateralWithdrawn(_creditId, _to, _amount);
}
/**
* @notice Withdraw excess tokens not being used as collateral
*
* @param _token token address
* @param _to token receiver address
*/
function withdrawExcess(address _token, address _to) external {
require(TOKEN_REGISTRY.hasRole(DEFAULT_ADMIN_ROLE, msg.sender), "OnlyGovernanceCanCall");
uint256 _excessAmount = IERC20(_token).balanceOf(address(this)) - totalCollateral[_token];
require(_excessAmount != 0, "C: NoExcess");
IERC20(_token).safeTransfer(_to, _excessAmount);
emit ExcessTokensWithdrawn(_token, _to, _excessAmount);
}
/**
* @notice Returns credits required to enter a tournament denominated in another collateral type
*
* @param _fee Collateral fee to convert to credits in wei
* @param _tokenPair Price feed pair ID for conversion
* @param _creditRatio Ratio of target currency to credits in wei
*/
function getCreditsRequired(uint256 _fee, bytes32 _tokenPair, uint256 _creditRatio) public view returns (uint256) {
if (_tokenPair == bytes32(0)) return _fee;
uint256 _price = priceFeed.getPrice(_tokenPair);
uint256 _collateral = _fee.div(_price);
uint256 _creditsRequired = uint256(1).max(_collateral.ceilDiv(_creditRatio));
return _creditsRequired;
}
/**
* @notice Returns the split between credits, tickets and bonus cash for a user entering a specific tournament
*
* @param _account the user wallet
* @param _creditId token address of the credit type to retrieve the split for
* @param _entryFee the total entry fee for user and tournament
*/
function getEntrySplit(
address _account,
address _creditId,
uint256 _entryFee
) external view returns (uint256 _amountCredits, uint256 _amountTickets, uint256 _amountBonusCash) {
uint256 _ticketBalance = TICKETS.balanceOf(_account, _creditId);
uint256 _creditBalance = CREDITS.balanceOf(_account, _creditId);
_amountBonusCash = BONUS_CASH.getBonusCashForEntry(
_account,
_creditId,
_ticketBalance,
_creditBalance,
_entryFee
);
uint256 _entryFeeAfterBonusCash = _entryFee - _amountBonusCash;
_amountCredits = _creditBalance.min(_entryFeeAfterBonusCash);
_amountTickets = _entryFeeAfterBonusCash - _amountCredits;
require(_ticketBalance >= _amountTickets, "T: InsufficientBalance");
}
function _getNextTournamentId() private returns (uint256) {
unchecked {
return ++tournamentCount;
}
}
function _validateTournamentId(uint256 _tournamentId) private view {
require(_tournamentId <= tournamentCount && _tournamentId > 0, "T: InvalidTournamentId");
}
function _validateTournamentConfig(Config memory _c) private view {
require(_c.endDate > _c.startDate, "T: EndDateBeforeStartDate");
require(_c.entryLimit > 0, "T: EntryLimitZero");
require(_c.ticketProfitToTickets <= 1e18, "T: InvalidPercent");
require(_c.creditProfitToTickets <= 1e18, "T: InvalidPercent");
require(_c.creditEntryToTickets <= 1e18, "T: InvalidPercent");
if (_c.priceFeedPair != bytes32(0)) {
require(priceFeed.getPrice(_c.priceFeedPair) > 0, "T: InvalidPriceFeedPair");
}
}
function _updateTournamentConfig(Config storage _config, uint256 _tournamentId, Config memory _c) private {
_config.startDate = _c.startDate;
_config.endDate = _c.endDate;
_config.entryLimit = _c.entryLimit;
_config.rebuyLimit = _c.rebuyLimit;
_config.entryFee = _c.entryFee;
_config.rebuyFee = _c.rebuyFee;
_config.ticketProfitToTickets = _c.ticketProfitToTickets;
_config.creditProfitToTickets = _c.creditProfitToTickets;
_config.creditEntryToTickets = _c.creditEntryToTickets;
_config.maxEntriesPerRoom = _c.maxEntriesPerRoom;
_config.bonusCollateral = _c.bonusCollateral;
_config.payoutDuration = _c.payoutDuration;
_config.entryDuration = _c.entryDuration;
_config.tournamentDuration = _c.tournamentDuration;
emit TournamentConfigUpdated(_tournamentId, _c);
}
function _resolveUndercollateralization(Room storage _room, address _creditId, uint256 _totalPayout) private {
uint256 _amountMissing = _totalPayout - _room.totalPrizePool;
if (
_amountMissing <= collateralResolverMax[_creditId] &&
_amountMissing <= emergencyCollateralBalance[_creditId]
) {
_room.totalPrizePool += _amountMissing;
_room.collateral += _amountMissing;
emergencyCollateralBalance[_creditId] -= _amountMissing;
} else {
revert("T: PrizePoolExceeded");
}
}
function _validateEntrance(
uint256 _tournamentId,
uint256 _roomId,
address _account,
uint256 _entryAmount
) private returns (bool _isRebuy) {
_validateTournamentId(_tournamentId);
Config storage _config = tournaments[_tournamentId];
Room storage _room = rooms[_tournamentId][_roomId];
Entry storage _entry = players[_tournamentId][_account].entries[_roomId];
EntryData storage _entryData = players[_tournamentId][_account];
if (_room.startDate == 0) {
_createRoom(_tournamentId, _roomId, 0, _config, _room);
} else {
require(block.timestamp >= _room.startDate - _config.entryDuration, "T: RoomNotActive");
}
uint256 _cutoffDate = _room.startDate;
uint256 _configuredFee;
_isRebuy = _entry.totalCollateralPaid > 0;
if (_isRebuy) {
_configuredFee = _config.rebuyFee;
_cutoffDate = _room.endDate;
require(_entry.rebuyCount < _config.rebuyLimit, "T: RebuyLimitReached");
unchecked {
_entry.rebuyCount += 1;
}
} else {
_configuredFee = _config.entryFee;
require(_entryData.entryCount < _config.entryLimit, "T: PlayerEntryLimitReached");
require(_room.totalEntries < _config.maxEntriesPerRoom, "T: RoomEntryLimitReached");
unchecked {
_entryData.entryCount += 1;
_room.totalEntries += 1;
}
}
require(block.timestamp < _cutoffDate, "T: TournamentStartedOrOver");
if (_config.isExactFee) {
require(_entryAmount == _configuredFee, "T: InvalidEntryAmount");
} else {
require(_entryAmount >= _configuredFee, "T: InvalidEntryAmount");
}
}
function _createRoom(
uint256 _tournamentId,
uint256 _roomId,
uint64 _openTimestamp,
Config storage _config,
Room storage _room
) private {
_openTimestamp = _openTimestamp != 0 ? _openTimestamp : uint64(block.timestamp);
require(_openTimestamp >= _config.startDate && _openTimestamp < _config.endDate, "T: InvalidStartDate");
_room.startDate = _openTimestamp + _config.entryDuration;
_room.endDate = _room.startDate + _config.tournamentDuration;
_room.payoutEndDate = uint56(_room.endDate + _config.payoutDuration);
emit RoomOpened(_tournamentId, _roomId);
}
function _handleCreditSwapOrPurchaseIfNeeded(
address _account,
address _swapFromCredit,
uint256 _swapMaxCollateralIn,
address _creditId,
uint256 _fee,
uint256 _creditBalance,
uint256 _ticketBalance
) private returns (uint256 _amountCreditsPurchased) {
if (msg.value > 0) {
CREDITS.purchaseCredits{value: msg.value}(_fee, _account, _creditId, address(this));
_amountCreditsPurchased = _fee;
} else if (_swapFromCredit != address(0)) {
require(swapEnabled[_swapFromCredit][_creditId], "T: SwapNotEnabled");
CREDITS.swap(
_swapFromCredit,
_creditId,
_account,
_fee,
block.timestamp + swapDeadline,
_swapMaxCollateralIn,
swapExecutor
);
_amountCreditsPurchased = _fee;
} else if (_ticketBalance + _creditBalance < _fee) {
uint256 _ratio = CREDITS.tokenPerCreditRatio(_creditId);
uint256 _amountNeeded = _fee - _ticketBalance - _creditBalance;
uint256 _collateralAmount = _amountNeeded * _ratio;
IERC20(_creditId).safeTransferFrom(_account, address(this), _collateralAmount);
IERC20(_creditId).forceApprove(address(CREDITS), _collateralAmount);
CREDITS.purchaseCredits(_amountNeeded, _account, _creditId, address(this));
_amountCreditsPurchased = _amountNeeded;
}
}
function _payFee(
EntryParams memory _params,
uint256 _creditsAndTicketsRequired,
uint256 _creditsAndTicketsRequiredAfterBonusCash,
uint256 _creditBalance
) private returns (uint256 _collateral) {
Config storage _config = tournaments[_params.tournamentId];
uint256 _creditsRequired = _creditBalance.min(_creditsAndTicketsRequiredAfterBonusCash);
uint256 _ticketsRequired = _creditsAndTicketsRequiredAfterBonusCash - _creditsRequired;
if (_creditsRequired > 0) {
CREDITS.release(_params.account, _config.creditId, _creditsRequired);
}
if (_ticketsRequired > 0) {
TICKETS.release(_params.account, address(this), _config.creditId, _ticketsRequired, false);
}
uint256 _totalCollateral = _config.creditRatio * _creditsAndTicketsRequired;
uint256 _totalFee = _disperseProtocolFee(_params.account, _config, _totalCollateral, _params.tournamentId);
PLAYTHROUGH_TRACKER.progressAccount(_params.account, _config.creditId, msg.sender, _creditsAndTicketsRequired);
return
_updateRoomAndEntry(
_params.tournamentId,
_params.roomId,
_params.account,
_ticketsRequired * _config.creditRatio,
_creditsRequired * _config.creditRatio,
_totalCollateral,
_totalFee,
_config.creditId
);
}
function _updateRoomAndEntry(
uint256 _tournamentId,
uint256 _roomId,
address _account,
uint256 _ticketBasedCollateralAmount,
uint256 _creditBasedCollateralAmount,
uint256 _totalCollateral,
uint256 _totalFee,
address _creditId
) private returns (uint256 _collateral) {
Room storage _room = rooms[_tournamentId][_roomId];
Entry storage _entry = players[_tournamentId][_account].entries[_roomId];
unchecked {
_collateral = _totalCollateral - _totalFee;
uint256 _totalBalance = _ticketBasedCollateralAmount + _creditBasedCollateralAmount;
uint256 _newCollateral = _totalBalance - _totalBalance.min(_totalFee);
_room.totalPrizePool += _collateral;
_room.collateral += _newCollateral;
_entry.totalCollateralPaid += _totalCollateral;
_entry.ticketBasedCollateral += _ticketBasedCollateralAmount;
_entry.creditBasedCollateral += _creditBasedCollateralAmount;
totalCollateral[_creditId] += _newCollateral;
}
}
function _disperseProtocolFee(
address _account,
Config storage _config,
uint256 _totalCollateral,
uint256 _tournamentId
) private returns (uint256) {
uint256 _currentBalance = IERC20(_config.creditId).balanceOf(address(this));
(address[] memory _addrs, uint256[] memory _amounts, uint256 _totalFee) = FEE_SPLITTER.calculateFees(
gameDev,
_account,
_totalCollateral,
devFeePercentage
);
if (_currentBalance < _totalFee) {
BONUS_CASH.collateralPayout(_config.creditId, _tournamentId, _totalFee - _currentBalance);
}
for (uint256 i; i < _addrs.length; i++) {
if (_addrs[i] != address(0) && _amounts[i] != 0) {
IERC20(_config.creditId).safeTransfer(_addrs[i], _amounts[i]);
}
}
return _totalFee;
}
function _processPayout(
uint256 _tournamentId,
Result memory _result,
uint256 _roomId,
Config storage _config
) private returns (uint256 _amountTickets, uint256 _amountCredits) {
EntryData storage _entryData = players[_tournamentId][_result.player];
Entry storage _entry = _entryData.entries[_roomId];
require(_entry.ticketBasedCollateral > 0 || _entry.creditBasedCollateral > 0, "T: PlayerNotInRoom");
require(_entry.payoutReceived == false, "T: PayoutAlreadyReceived");
_entry.payoutReceived = true;
(uint256 _ticketBasedMultiplier, uint256 _creditBasedMultiplier) = _calculatePayoutMultipliers(
_result.multiplier,
_entry,
_config
);
_amountTickets = _config.entryFee.mul(_ticketBasedMultiplier);
_amountCredits = _config.entryFee.mul(_creditBasedMultiplier);
}
function _calculatePayoutMultipliers(
uint256 _multiplier,
Entry storage _entry,
Config storage _c
) private view returns (uint256 _ticketBasedMultiplier, uint256 _creditBasedMultiplier) {
uint256 _totalCollateralPaid = _entry.totalCollateralPaid;
uint256 _percentTickets = _entry.ticketBasedCollateral.div(_totalCollateralPaid);
uint256 _percentCredits = _entry.creditBasedCollateral.div(_totalCollateralPaid);
uint256 _creditValue = _c.entryFee * _c.creditRatio * _percentCredits / 1e18;
uint256 _ticketValue = _c.entryFee * _c.creditRatio * _percentTickets / 1e18;
if (_multiplier > 1e18) {
// General case where there is a nonzero profit
(_ticketBasedMultiplier, _creditBasedMultiplier) = _calculateMultipliersForProfit(
_multiplier,
_c,
_ticketValue,
_creditValue,
1e18 - _percentTickets - _percentCredits
);
} else if (_percentTickets + _percentCredits <= _multiplier) {
// Case where all tickets/credits are recouped, but any bonus cash is not
uint256 _converted = _c.creditEntryToTickets * _percentCredits / 1e18;
uint256 _convDiff = 1e18 - _c.creditEntryToTickets;
_ticketBasedMultiplier = _percentTickets + _converted;
_creditBasedMultiplier = _convDiff.mul(_percentCredits);
} else if (_percentTickets <= _multiplier) {
// Case where some credits are not recouped
uint256 _excess = _multiplier - _percentTickets;
uint256 _creditsDiff = _excess.mul(_c.creditEntryToTickets);
_ticketBasedMultiplier = _percentTickets + _creditsDiff;
_creditBasedMultiplier = _multiplier - _ticketBasedMultiplier;
} else {
// Case where some tickets are not recouped
_ticketBasedMultiplier = _multiplier;
}
}
function _calculateMultipliersForProfit(
uint256 _multiplier,
Config memory _c,
uint256 _ticketBasedCollateral,
uint256 _creditBasedCollateral,
uint256 _percentBonus
) private pure returns (uint256 _ticketMultiplier, uint256 _creditMultiplier) {
uint256 _profit = _multiplier - 1e18;
uint256 _ticketProfitToTickets = _profit.mul(_c.ticketProfitToTickets);
uint256 _creditProfitToTickets = _profit.mul(_c.creditProfitToTickets);
uint256 _ticketsToTickets = _ticketBasedCollateral.mul(1e18 + _ticketProfitToTickets);
uint256 _creditsToTickets = _creditBasedCollateral.mul(_c.creditEntryToTickets + _creditProfitToTickets);
_ticketMultiplier = (_ticketsToTickets + _creditsToTickets).div(_c.entryFee * _c.creditRatio);
_creditMultiplier = _multiplier - _ticketMultiplier - _percentBonus;
}
function _requestBonusCashCollateral(
Room storage _room,
Config storage _config,
uint256 _collateralTotal,
uint256 _tournamentId
) private {
uint256 _amountNeeded = _config.bonusCollateral.max(_collateralTotal - _room.collateral);
unchecked {
uint256 _newCollateral = _amountNeeded - _collateralTotal;
_room.collateral += _newCollateral;
totalCollateral[_config.creditId] += _newCollateral;
}
_room.bonusCashCollected = true;
BONUS_CASH.collateralPayout(_config.creditId, _tournamentId, _amountNeeded);
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
interface ISwapExecutor {
error ZeroAddress();
event FeeSet(uint24 fee);
function executeSwap(
address _fromToken,
address _toToken,
uint256 _amount,
uint256 _deadline,
uint256 _amountOutMinimum
) external returns (uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
library PVMath {
function mul(uint256 a, uint256 b) internal pure returns (uint256) {
return (a * b) / 1e18;
}
function div(uint256 a, uint256 b) internal pure returns (uint256) {
return (a * 1e18) / b;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {ICredits} from "../credits/ICredits.sol";
interface IBonusCash {
struct BonusCashInfo {
uint256 totalSupply;
address creditId;
uint256 creditRatio;
uint256 collateral;
uint256 targetEntryPct;
uint256 activeCount;
address admin;
bool invalidated;
// gameAddress => isIncluded
mapping(address => bool) included;
// playerAddress => startingBalance
mapping(address => uint256) startingBalance;
// gameAddress => tournamentId => hasActiveTournament
mapping(address => mapping(uint256 => bool)) isActive;
// gameAddress => tournamentId => pendingBonusCashAmount
mapping(address => mapping(uint256 => uint256)) pendingSupply;
}
struct Distribution {
uint256 offeringId;
address[] players;
uint256[] amounts;
uint256[] playthroughRequirements;
bytes[] sigs;
}
event MinCollateralRatioSet(uint256 minCollateralRatio);
event OfferingUpdated(
uint256 offeringId,
address creditId,
uint256 collateral,
uint256 targetEntryPct,
address[] gamesAdded,
address[] gamesRemoved,
address admin
);
event PlaythroughUndone(uint256 offeringId, address[] players);
event BonusCashDistributed(uint256 offeringId, address[] players, uint256[] amounts);
event BonusCashSpent(uint256 offeringId, uint256 tournamentId, address game, address player, uint256 amount);
event CollateralSent(uint256 offeringId, uint256 tournamentId, uint256 amount, address game);
event TournamentEnded(address game, uint256 tournamentId);
event OfferingInvalidated(uint256 offeringId);
event CollateralWithdrawn(uint256 offeringId, address to, uint256 amount);
event CreditsSet(ICredits credits);
event PlaythroughTrackerSet(address playthroughTracker);
event MaxAllowedPlaythroughSet(uint256 playthrough);
event PlayerOptedOut(address player, uint256 offeringId);
function creditToGameToOfferingId(address creditId, address game) external view returns (uint256);
function gameBalanceOf(address game, address creditId, address player) external view returns (uint256);
function gameTargetEntryPct(address game, address creditId) external view returns (uint256);
function spendRequiredAmount(
address _account,
address _token,
uint256 _amountTickets,
uint256 _amountCredits,
uint256 _tournamentId,
uint256 _fee
) external returns (uint256);
function getBonusCashForEntry(
address _account,
address _token,
uint256 _ticketBalance,
uint256 _creditBalance,
uint256 _entryFee
) external view returns (uint256 _requiredAmount);
function collateralPayout(address _creditId, uint256 _tournamentId, uint256 _amount) external;
function endTournament(address _creditId, uint256 _tournamentId, uint256 _collateralToReturn) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";
import {ISemiFungibleSoulboundTokenUpgradeable} from "../sfst/ISemiFungibleSoulboundTokenUpgradeable.sol";
import {ISwapExecutor} from "../../interfaces/ISwapExecutor.sol";
interface ICredits is IAccessControl, ISemiFungibleSoulboundTokenUpgradeable {
error Credits__ZeroAddress();
event WapeSet(address wape);
event PlaythroughTrackerSet(address playthroughTracker);
event AllowanceWithdrawal(address token, address receiver, uint256 amount);
event CreditsPurchased(address token, address payFrom, address mintTo, uint256 amount);
event CreditTypeConfigured(address token, uint256 ratio);
event BonusCashSet(address bonusCash);
event TicketsSet(address tickets);
event CreditsReleased(address _from, address _to, address _token, uint256 _amount);
event FeeReleased(
address account,
address token,
uint256 amount,
uint256 tournamentId,
uint256 collateralAmount,
uint256 amountLiquid,
uint256 amountIlliquid
);
event ExcessTokensWithdrawn(address token, address to, uint256 excessAmount);
event CreditsSwapped(address fromToken, address toToken, uint256 tokensIn, uint256 creditsOut);
event SwapImplEnabledChanged(address indexed swapImpl, bool enabled);
function release(address _from, address _token, uint256 _amount) external returns (uint256 _releasedAmount);
function purchaseCredits(uint256 _amount, address _mintTo, address _token, address _payFrom) external payable;
function mintBatch(address _creditId, address[] memory _players, uint256[] memory _amounts) external;
function tokenPerCreditRatio(address _creditId) external view returns (uint256);
function purchaseCreditsWithGivenCollateral(
uint256 _collateralAmount,
address _mintTo,
address _tokenAddress,
address _payFrom
) external payable returns (uint256);
function swap(
address _fromToken,
address _toToken,
address _account,
uint256 _creditsRequired,
uint256 _deadline,
uint256 _maxAmountTokensIn,
ISwapExecutor _swapImpl
) external;
function swapImplEnabled(address _swapImpl) external view returns (bool);
function balanceOf(address account, address token) external view returns (uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
interface ISemiFungibleSoulboundTokenUpgradeable is IERC165 {
/**
* @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
* @param sender Address whose tokens are being transferred.
* @param balance Current balance for the interacting account.
* @param needed Minimum amount required to perform a transfer.
* @param tokenId Identifier number of a token.
*/
error InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);
/**
* @dev Indicates a failure with the token `sender`. Used in transfers.
* @param sender Address whose tokens are being transferred.
*/
error InvalidSender(address sender);
/**
* @dev Indicates a failure with the token `receiver`. Used in transfers.
* @param receiver Address to which tokens are being transferred.
*/
error InvalidReceiver(address receiver);
/**
* @dev Indicates a failure with the token `value`. Used in transfers.
* @param value value of tokens to transfer.
*/
error InvalidValue(uint256 value);
/**
* @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
* Used in batch transfers.
* @param idsLength Length of the array of token identifiers
* @param valuesLength Length of the array of token amounts
*/
error InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
/**
* @dev Emitted when `value` amount of tokens of type `id` are transferred from `from` to `to` by `operator`.
*/
event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);
/**
* @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
* transfers.
*/
event TransferBatch(
address indexed operator,
address indexed from,
address indexed to,
uint256[] ids,
uint256[] values
);
/**
* @dev Returns the value of tokens of token type `id` owned by `account`.
*
* Requirements:
*
* - `account` cannot be the zero address.
*/
function balanceOf(address account, uint256 id) external view returns (uint256);
/**
* @dev Batched version of {balanceOf}.
*
* Requirements:
*
* - `accounts` and `ids` must have the same length.
*/
function balanceOfBatch(
address[] calldata accounts,
uint256[] calldata ids
) external view returns (uint256[] memory);
/**
* @dev Transfers a `value` amount of tokens of type `id` from `from` to `to`.
*
* Emits a {TransferSingle} event.
*
* Requirements:
*
* - `to` cannot be the zero address.
* - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
* - `from` must have a balance of tokens of type `id` of at least `value` amount.
*/
function transferFrom(address from, address to, uint256 id, uint256 value) external;
/**
* Emits either a {TransferSingle} or a {TransferBatch} event, depending on the length of the array arguments.
*
* Requirements:
*
* - `ids` and `values` must have the same length.
*/
function batchTransferFrom(address from, address to, uint256[] calldata ids, uint256[] calldata values) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {ISemiFungibleSoulboundTokenUpgradeable} from "../sfst/ISemiFungibleSoulboundTokenUpgradeable.sol";
interface ITickets is ISemiFungibleSoulboundTokenUpgradeable {
event TicketTypeConfigured(address token, uint256 ratio);
event WapeSet(address wape);
event PlaythroughTrackerSet(address playthroughTracker);
event ExcessTokensWithdrawn(address token, address to, uint256 excessAmount);
function tokensPerTicket(address token) external view returns (uint256);
function mintBatch(address _token, address[] memory _players, uint256[] memory _amounts) external;
function release(
address _from,
address _to,
address _token,
uint256 _amount,
bool _nativeApe
) external returns (uint256 _releasedAmount);
function configureTicketType(address _tokenContract, uint256 _tokenPerCreditRatio) external;
function balanceOf(address account, address token) external view returns (uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";
interface ITokenRegistry is IAccessControl {
event TokenUpdated(address token, bool approved);
function isApproved(address _token) external view returns (bool);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
interface IPriceFeed {
function getPrice(bytes32 _priceFeedId) external view returns (uint256);
}